如何在Excel中突出显示不同颜色的重复值？

在Excel中，我们可以用一种颜色轻松地突出显示一列中的重复值 条件格式但是，有时候，我们需要突出显示不同颜色的重复值，以便快速轻松地识别重复项，如下面的截图所示。 你怎么能在Excel中解决这个任务？

事实上，我们没有直接的方式来完成这项工作在Excel中，但是，下面的VBA代码可以帮助你，请做如下：

使用VBA代码突出显示具有不同颜色的列中的重复值

1、选择要用不同颜色突出显示重复项的值列，然后按住 ALT + F11 键打开 Microsoft Visual Basic for Applications 窗口。

2、点击 插页 > 模块，并将以下代码粘贴到 模块 窗口。

VBA代码：突出显示不同颜色的重复值：

Sub ColorCompanyDuplicates()
'Updateby Extendoffice 20160704
    Dim xRg As Range
    Dim xTxt As String
    Dim xCell As Range
    Dim xChar As String
    Dim xCellPre As Range
    Dim xCIndex As Long
    Dim xCol As Collection
    Dim I As Long
    On Error Resume Next
    If ActiveWindow.RangeSelection.Count > 1 Then
      xTxt = ActiveWindow.RangeSelection.AddressLocal
    Else
      xTxt = ActiveSheet.UsedRange.AddressLocal
    End If
    Set xRg = Application.InputBox("please select the data range:", "Kutools for Excel", xTxt, , , , , 8)
    If xRg Is Nothing Then Exit Sub
    xCIndex = 2
    Set xCol = New Collection
    For Each xCell In xRg
      On Error Resume Next
      xCol.Add xCell, xCell.Text
      If Err.Number = 457 Then
        xCIndex = xCIndex + 1
        Set xCellPre = xCol(xCell.Text)
        If xCellPre.Interior.ColorIndex = xlNone Then xCellPre.Interior.ColorIndex = xCIndex
        xCell.Interior.ColorIndex = xCellPre.Interior.ColorIndex
      ElseIf Err.Number = 9 Then
        MsgBox "Too many duplicate companies!", vbCritical, "Kutools for Excel"
        Exit Sub
      End If
      On Error GoTo 0
    Next
End Sub

3、然后按 F5 键来运行这个代码，并且一个提示框会提醒你选择你想要突出显示重复值的数据范围，看截图：

4、然后点击 OK 按钮，所有重复的值都以不同的颜色突出显示，请参见截图：